1000 ' HELP Command March 20, 1982
1005 ' by Dan Dugan -- public domain
1010 DEFINT A-Z
1020 COMMON I,J,K,X,Y,T$,R$,S$,T1$,SKIPPARSE,FT,SEARCH,

	C,N,NC,P6,P7,P8,P9,PI,S,T,T1,T2,C(),B$(),N$(),

	SEARCHWORD$(),SEARCHFIELD(),SKIPWORD$(),LOOKFIELD(),DD$(),F$,FT$
1030 GOTO 1070
1040 '



				(SUB) CLEAR SCREEN (TERM DEP)


1050 PRINT CHR$(12);
1060 RETURN
1070 '



				HELP COMMAND


1080 GOSUB 1040 'cs
1090 '


				TEST FOR PRESENCE OF FILE


1100 ON ERROR GOTO 1130
1110 OPEN"I",3,DD$(5)+"DHELP.DOC"
1120 ON ERROR GOTO 0: GOTO 1160 '		if OK then go on
1130	IF ERR=53 THEN

		PRINT:PRINT"No help text file present":

		RESUME 1260
1140	ON ERROR GOTO 0
1150 '


				READ 23 LINES AT A TIME


1160 GOSUB 1040 'cs
1170 FOR I=1 TO 23
1180	IF EOF(3) THEN CLOSE 3: GOTO 1290	'last
1190	LINE INPUT #3, L$
1200	PRINT L$
1210 NEXT I
1220 PRINT"For next page, hit SPACE; use '\' to go back, ESC to return to editor.";
1225 A$=INPUT$(1)
1226 GOSUB 1040
1230 IF A$=CHR$(27) THEN 1260	'done
1240 IF A$="\" THEN CLOSE 3:GOTO 1070
1250 GOTO 1170
1260 '


				FINISH


1270 CLOSE 3
1280 PRINT"Re-loading DIMS file editor (DEDIT).":CHAIN DD$(1)+"DEDIT",1000
1290 '


				LAST PAGE


1300 PRINT"Last help page.  Hit SPACE to return to editor, or '\' to read again.";
1310 A$=INPUT$(1)
1312 GOSUB 1040
1314 IF A$=CHR$(27) THEN 1260
1320 IF A$="\" THEN CLOSE 3:GOTO 1070
1330 GOTO 1260
